home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / dtbmv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  11.2 KB  |  346 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE DTBMV ( UPLO, TRANS, DIAG, N, K, A, LDA, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, K, LDA, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       DOUBLE PRECISION   A( LDA, * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  DTBMV  performs one of the matrix-vector operations
  16. *
  17. *     x := A*x,   or   x := A'*x,
  18. *
  19. *  where x is an n element vector and  A is an n by n unit, or non-unit,
  20. *  upper or lower triangular band matrix, with ( k + 1 ) diagonals.
  21. *
  22. *  Parameters
  23. *  ==========
  24. *
  25. *  UPLO   - CHARACTER*1.
  26. *           On entry, UPLO specifies whether the matrix is an upper or
  27. *           lower triangular matrix as follows:
  28. *
  29. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  30. *
  31. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  32. *
  33. *           Unchanged on exit.
  34. *
  35. *  TRANS  - CHARACTER*1.
  36. *           On entry, TRANS specifies the operation to be performed as
  37. *           follows:
  38. *
  39. *              TRANS = 'N' or 'n'   x := A*x.
  40. *
  41. *              TRANS = 'T' or 't'   x := A'*x.
  42. *
  43. *              TRANS = 'C' or 'c'   x := A'*x.
  44. *
  45. *           Unchanged on exit.
  46. *
  47. *  DIAG   - CHARACTER*1.
  48. *           On entry, DIAG specifies whether or not A is unit
  49. *           triangular as follows:
  50. *
  51. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  52. *
  53. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  54. *                                  triangular.
  55. *
  56. *           Unchanged on exit.
  57. *
  58. *  N      - INTEGER.
  59. *           On entry, N specifies the order of the matrix A.
  60. *           N must be at least zero.
  61. *           Unchanged on exit.
  62. *
  63. *  K      - INTEGER.
  64. *           On entry with UPLO = 'U' or 'u', K specifies the number of
  65. *           super-diagonals of the matrix A.
  66. *           On entry with UPLO = 'L' or 'l', K specifies the number of
  67. *           sub-diagonals of the matrix A.
  68. *           K must satisfy  0 .le. K.
  69. *           Unchanged on exit.
  70. *
  71. *  A      - DOUBLE PRECISION array of DIMENSION ( LDA, n ).
  72. *           Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
  73. *           by n part of the array A must contain the upper triangular
  74. *           band part of the matrix of coefficients, supplied column by
  75. *           column, with the leading diagonal of the matrix in row
  76. *           ( k + 1 ) of the array, the first super-diagonal starting at
  77. *           position 2 in row k, and so on. The top left k by k triangle
  78. *           of the array A is not referenced.
  79. *           The following program segment will transfer an upper
  80. *           triangular band matrix from conventional full matrix storage
  81. *           to band storage:
  82. *
  83. *                 DO 20, J = 1, N
  84. *                    M = K + 1 - J
  85. *                    DO 10, I = MAX( 1, J - K ), J
  86. *                       A( M + I, J ) = matrix( I, J )
  87. *              10    CONTINUE
  88. *              20 CONTINUE
  89. *
  90. *           Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
  91. *           by n part of the array A must contain the lower triangular
  92. *           band part of the matrix of coefficients, supplied column by
  93. *           column, with the leading diagonal of the matrix in row 1 of
  94. *           the array, the first sub-diagonal starting at position 1 in
  95. *           row 2, and so on. The bottom right k by k triangle of the
  96. *           array A is not referenced.
  97. *           The following program segment will transfer a lower
  98. *           triangular band matrix from conventional full matrix storage
  99. *           to band storage:
  100. *
  101. *                 DO 20, J = 1, N
  102. *                    M = 1 - J
  103. *                    DO 10, I = J, MIN( N, J + K )
  104. *                       A( M + I, J ) = matrix( I, J )
  105. *              10    CONTINUE
  106. *              20 CONTINUE
  107. *
  108. *           Note that when DIAG = 'U' or 'u' the elements of the array A
  109. *           corresponding to the diagonal elements of the matrix are not
  110. *           referenced, but are assumed to be unity.
  111. *           Unchanged on exit.
  112. *
  113. *  LDA    - INTEGER.
  114. *           On entry, LDA specifies the first dimension of A as declared
  115. *           in the calling (sub) program. LDA must be at least
  116. *           ( k + 1 ).
  117. *           Unchanged on exit.
  118. *
  119. *  X      - DOUBLE PRECISION array of dimension at least
  120. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  121. *           Before entry, the incremented array X must contain the n
  122. *           element vector x. On exit, X is overwritten with the
  123. *           tranformed vector x.
  124. *
  125. *  INCX   - INTEGER.
  126. *           On entry, INCX specifies the increment for the elements of
  127. *           X. INCX must not be zero.
  128. *           Unchanged on exit.
  129. *
  130. *
  131. *  Level 2 Blas routine.
  132. *
  133. *  -- Written on 22-October-1986.
  134. *     Jack Dongarra, Argonne National Lab.
  135. *     Jeremy Du Croz, Nag Central Office.
  136. *     Sven Hammarling, Nag Central Office.
  137. *     Richard Hanson, Sandia National Labs.
  138. *
  139. *
  140. *     .. Parameters ..
  141.       DOUBLE PRECISION   ZERO
  142.       PARAMETER        ( ZERO = 0.0D+0 )
  143. *     .. Local Scalars ..
  144.       DOUBLE PRECISION   TEMP
  145.       INTEGER            I, INFO, IX, J, JX, KPLUS1, KX, L
  146.       LOGICAL            NOUNIT
  147. *     .. External Functions ..
  148.       LOGICAL            LSAME
  149.       EXTERNAL           LSAME
  150. *     .. External Subroutines ..
  151.       EXTERNAL           XERBLA
  152. *     .. Intrinsic Functions ..
  153.       INTRINSIC          MAX, MIN
  154. *     ..
  155. *     .. Executable Statements ..
  156. *
  157. *     Test the input parameters.
  158. *
  159.       INFO = 0
  160.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  161.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  162.          INFO = 1
  163.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  164.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  165.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  166.          INFO = 2
  167.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  168.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  169.          INFO = 3
  170.       ELSE IF( N.LT.0 )THEN
  171.          INFO = 4
  172.       ELSE IF( K.LT.0 )THEN
  173.          INFO = 5
  174.       ELSE IF( LDA.LT.( K + 1 ) )THEN
  175.          INFO = 7
  176.       ELSE IF( INCX.EQ.0 )THEN
  177.          INFO = 9
  178.       END IF
  179.       IF( INFO.NE.0 )THEN
  180.          CALL XERBLA( 'DTBMV ', INFO )
  181.          RETURN
  182.       END IF
  183. *
  184. *     Quick return if possible.
  185. *
  186.       IF( N.EQ.0 )
  187.      $   RETURN
  188. *
  189.       NOUNIT = LSAME( DIAG, 'N' )
  190. *
  191. *     Set up the start point in X if the increment is not unity. This
  192. *     will be  ( N - 1 )*INCX   too small for descending loops.
  193. *
  194.       IF( INCX.LE.0 )THEN
  195.          KX = 1 - ( N - 1 )*INCX
  196.       ELSE IF( INCX.NE.1 )THEN
  197.          KX = 1
  198.       END IF
  199. *
  200. *     Start the operations. In this version the elements of A are
  201. *     accessed sequentially with one pass through A.
  202. *
  203.       IF( LSAME( TRANS, 'N' ) )THEN
  204. *
  205. *         Form  x := A*x.
  206. *
  207.          IF( LSAME( UPLO, 'U' ) )THEN
  208.             KPLUS1 = K + 1
  209.             IF( INCX.EQ.1 )THEN
  210.                DO 20, J = 1, N
  211.                   IF( X( J ).NE.ZERO )THEN
  212.                      TEMP = X( J )
  213.                      L    = KPLUS1 - J
  214.                      DO 10, I = MAX( 1, J - K ), J - 1
  215.                         X( I ) = X( I ) + TEMP*A( L + I, J )
  216.    10                CONTINUE
  217.                      IF( NOUNIT )
  218.      $                  X( J ) = X( J )*A( KPLUS1, J )
  219.                   END IF
  220.    20          CONTINUE
  221.             ELSE
  222.                JX = KX
  223.                DO 40, J = 1, N
  224.                   IF( X( JX ).NE.ZERO )THEN
  225.                      TEMP = X( JX )
  226.                      IX   = KX
  227.                      L    = KPLUS1  - J
  228.                      DO 30, I = MAX( 1, J - K ), J - 1
  229.                         X( IX ) = X( IX ) + TEMP*A( L + I, J )
  230.                         IX      = IX      + INCX
  231.    30                CONTINUE
  232.                      IF( NOUNIT )
  233.      $                  X( JX ) = X( JX )*A( KPLUS1, J )
  234.                   END IF
  235.                   JX = JX + INCX
  236.                   IF( J.GT.K )
  237.      $               KX = KX + INCX
  238.    40          CONTINUE
  239.             END IF
  240.          ELSE
  241.             IF( INCX.EQ.1 )THEN
  242.                DO 60, J = N, 1, -1
  243.                   IF( X( J ).NE.ZERO )THEN
  244.                      TEMP = X( J )
  245.                      L    = 1      - J
  246.                      DO 50, I = MIN( N, J + K ), J + 1, -1
  247.                         X( I ) = X( I ) + TEMP*A( L + I, J )
  248.    50                CONTINUE
  249.                      IF( NOUNIT )
  250.      $                  X( J ) = X( J )*A( 1, J )
  251.                   END IF
  252.    60          CONTINUE
  253.             ELSE
  254.                KX = KX + ( N - 1 )*INCX
  255.                JX = KX
  256.                DO 80, J = N, 1, -1
  257.                   IF( X( JX ).NE.ZERO )THEN
  258.                      TEMP = X( JX )
  259.                      IX   = KX
  260.                      L    = 1       - J
  261.                      DO 70, I = MIN( N, J + K ), J + 1, -1
  262.                         X( IX ) = X( IX ) + TEMP*A( L + I, J )
  263.                         IX      = IX      - INCX
  264.    70                CONTINUE
  265.                      IF( NOUNIT )
  266.      $                  X( JX ) = X( JX )*A( 1, J )
  267.                   END IF
  268.                   JX = JX - INCX
  269.                   IF( ( N - J ).GE.K )
  270.      $               KX = KX - INCX
  271.    80          CONTINUE
  272.             END IF
  273.          END IF
  274.       ELSE
  275. *
  276. *        Form  x := A'*x.
  277. *
  278.          IF( LSAME( UPLO, 'U' ) )THEN
  279.             KPLUS1 = K + 1
  280.             IF( INCX.EQ.1 )THEN
  281.                DO 100, J = N, 1, -1
  282.                   TEMP = X( J )
  283.                   L    = KPLUS1 - J
  284.                   IF( NOUNIT )
  285.      $               TEMP = TEMP*A( KPLUS1, J )
  286.                   DO 90, I = J - 1, MAX( 1, J - K ), -1
  287.                      TEMP = TEMP + A( L + I, J )*X( I )
  288.    90             CONTINUE
  289.                   X( J ) = TEMP
  290.   100          CONTINUE
  291.             ELSE
  292.                KX = KX + ( N - 1 )*INCX
  293.                JX = KX
  294.                DO 120, J = N, 1, -1
  295.                   TEMP = X( JX )
  296.                   KX   = KX      - INCX
  297.                   IX   = KX
  298.                   L    = KPLUS1  - J
  299.                   IF( NOUNIT )
  300.      $               TEMP = TEMP*A( KPLUS1, J )
  301.                   DO 110, I = J - 1, MAX( 1, J - K ), -1
  302.                      TEMP = TEMP + A( L + I, J )*X( IX )
  303.                      IX   = IX   - INCX
  304.   110             CONTINUE
  305.                   X( JX ) = TEMP
  306.                   JX      = JX   - INCX
  307.   120          CONTINUE
  308.             END IF
  309.          ELSE
  310.             IF( INCX.EQ.1 )THEN
  311.                DO 140, J = 1, N
  312.                   TEMP = X( J )
  313.                   L    = 1      - J
  314.                   IF( NOUNIT )
  315.      $               TEMP = TEMP*A( 1, J )
  316.                   DO 130, I = J + 1, MIN( N, J + K )
  317.                      TEMP = TEMP + A( L + I, J )*X( I )
  318.   130             CONTINUE
  319.                   X( J ) = TEMP
  320.   140          CONTINUE
  321.             ELSE
  322.                JX = KX
  323.                DO 160, J = 1, N
  324.                   TEMP = X( JX )
  325.                   KX   = KX      + INCX
  326.                   IX   = KX
  327.                   L    = 1       - J
  328.                   IF( NOUNIT )
  329.      $               TEMP = TEMP*A( 1, J )
  330.                   DO 150, I = J + 1, MIN( N, J + K )
  331.                      TEMP = TEMP + A( L + I, J )*X( IX )
  332.                      IX   = IX   + INCX
  333.   150             CONTINUE
  334.                   X( JX ) = TEMP
  335.                   JX      = JX   + INCX
  336.   160          CONTINUE
  337.             END IF
  338.          END IF
  339.       END IF
  340. *
  341.       RETURN
  342. *
  343. *     End of DTBMV .
  344. *
  345.       END
  346.